Puzzle & Dragons (Mobile)

[puggsoy]

OK, so DATA000.BIN is kind of a weird format, can't tell what a lot of it means but I can see file offsets and sizes. At the very least they help with extracting by hand. DATA000.BIN seems to contain corresponding filenames for each file.

The other 3 .BIN files contain the data. DATA003.BIN has images, some of which I can manage to get:

A bit big

However, others are in a different format. Doesn't look to hard to find out (possibly 16-bit ARGB or something) but isn't supported by TextureFinder. I can maybe make a program to test it out later on.
The biggest issue is that I'm unsure how to tell which images are in which format. Some files contain multiple images with different formats, but I can't see any kind of format flag.

DATA002.BIN is weird, it just contains 3 small images, which are all 100% white. Probably negligible. DATA003.BIN contains sound effects in WAV format. Not terribly hard to extract.

You might be right about some sprites being externally downloaded, but the menu assets at least seem to be stored here. There is a lot of stuff to go through that I've only lightly scratched though, so it could be that everything is here.

I'll make an extraction script for the files anyway, which should get you the WAV files.

EDIT: Here's a QuickBMS script for them:

Code:

goto 0x20
getdstring FILE1 0x10
getdstring FILE2 0x10
getdstring FILE3 0x10

open FDSE FILE1 1
#open FDSE FILE2 2
open FDSE FILE3 3
open FDSE "DATA000.NAM" 4
savepos POS
set NMPOS POS
math NMPOS -= 0x50
get FSIZE asize 4

for NMPOS = NMPOS < FSIZE
    get v1 short
    get NUM short
    math NUM += 1
    get SIZE long
    get OFFSET long
    get DUMMY long
    
    goto NMPOS 4
    getct NM string 0x2E 4
    #get NM string 4
    
    if v1 == 0x8000
        if NUM == 1
            set NAME FILE1
            string NAME -= 4
            string NAME += "/"
            string NAME += NM
            
            goto OFFSET 1
            getdstring EXT 4 1
            
            if EXT == "TEX1"
                string NAME += ".btex"
            elif EXT == "BFNT"
                string NAME += ".bfnt"
            elif EXT == "DMSG"
                string NAME += ".bin"
            else
                string NAME += ".unk"
            endif
            
            log NAME OFFSET SIZE 1
        #elif NUM == 2
        #    set NAME FILE2
        #    string NAME -= 4
        #    string NAME += "/"
        #    string NAME += NM
        #    string NAME += ".btex"
            
        #    log NAME OFFSET SIZE 2
        elif NUM == 3
            set NAME FILE3
            string NAME -= 4
            string NAME += "/"
            string NAME += NM
            
            goto OFFSET 3
            getdstring EXT 4 3
            
            if EXT == "RIFF"
                string NAME += ".wav"
            else
                string NAME += ".unk"
            endif
            
            log NAME OFFSET SIZE 3
        endif
    endif
    
    savepos POS
    math NMPOS = POS
    math NMPOS -= 0x50
next

To use it all the files need to be in the same folder, and the file you select should be DATA000.BIN. In the output folder, you'll get two folders, DATA001 and DATA003. The latter contains the sound effects. The files in DATA001 are (mostly) textures, but not yet converted into a usable format.