Demon's model thread

[o0DemonBoy0o]

Got another for KH1


preview

Spoiler

http://www.mediafire.com/download.php?0fpz1of0bnaot4b

Also, I made a bms script to extract .mdls files from the kingdom hearts .ard files, or whatever you think might have mdls models.

Code:

# split files according to a search string
# very powerful for raw ripping
# (c) 2012-10-09 by AlphaTwentyThree of XeNTaX

set OFFSET 0
set SKIP -128 # skip bytes at start of search string
           # (use negative value if search identifier is after file start)
set NEGBIAS 0 # always positive!
set EXT ".mdls"
set NAMEPOS "" # if all files are the same type and you know the position of the names
set MINSIZE 4 # minimal size of extracted file

if SKIP < 0
   math OFFSET -= SKIP
endif
set SEARCH OFFSET
set QUIT 0
set SINGLE 0
set i 0
do
   goto SEARCH
   FindLoc SIZE string "MOBJ" 0 "" # set NEGBIAS 0, set SKIP -128

  
   if SIZE == ""
      set QUIT 1
      get SIZE asize
      if i == 0
         cleanexit
      endif
   else
      #print "split point found at offset %SIZE%"
   endif
   math SIZE -= OFFSET
   if SIZE == 0 # no residual data at start
      math i += 1
   elif SIZE > 4
      if NAMEPOS == ""
         get NAME basename
         if SINGLE != 1
            string NAME += "_"
            if i < 100
               string NAME += "0"
               if i < 10
                  string NAME += "0"
               endif
            endif
            string NAME += i
            if i != 0
               string NAME += EXT
            endif
         else
            if i != 0
               string NAME += EXT
            endif
         endif
      else
         savepos MYOFF
         goto NAMEPOS
         get NAME string
         savepos NAMEPOS
      endif
      math OFFSET += SKIP
      if QUIT != 1
         math SIZE -= SKIP
         math SIZE += NEGBIAS
      endif
      if SIZE > MINSIZE
         log NAME OFFSET SIZE
         math i += 1
      endif
   else
   endif
   if QUIT != 1
      math OFFSET += SIZE
      set SEARCH OFFSET
      math SEARCH += 4 # needs to be the length of the search string
      if SKIP > 0
         math SEARCH += SKIP
      else
         math SEARCH -* SKIP
      endif
   endif
while QUIT != 1

should note that some files it extracts might not actually be models